UA Developer: Clarion FAQ - The five questions posted most recently:

How to know the equate name of the control at run-time?

Thu, 18 Oct 2007 13:18:00 GMT

You may use undocumented procedure:
ClaFieldName(LONG),NAME('Cla$FieldName'),CSTRING,PROC

As mention above function is undocumented you may use legally user template (EXTENSION) that generates queue like:

		ControlNameQueue QUEUE
		Feq                UNSIGNED
		Name               STRING(100) ! or ASTRING
		                 END
		Run though all control and generate code for its fill:
		#FOR(%Control)
		  #IF(%Control)
		ControlNameQueue.Feq  = %Control
		ControlNameQueue.Name = '%Control'
		ADD(ControlNameQueue)
		  #ENDIF
		#ENDFOR
		SORT(ControlNameQueue, ControlNameQueue.Feq)
		After that equate name of control will be exctacted easy.

How to run application that will not be displayed in task bar?

Tue, 17 Jul 2007 08:32:00 GMT

It is possible to hide application only under Windows 95/98. It should use function RegisterServiceProcess:

! MAP Section

MAP

  MODULE('API')

    GetVersionEx(LONG),NAME('GetVersionExA'),SIGNED,PASCAL,PROC,RAW

    RegisterServiceProcess(ULONG dwProcessId,ULONG dwType),ULONG,RAW,PASCAL

    GetCurrentProcessId(),ULONG,RAW,PASCAL

  END

END



! Data Section

VER_PLATFORM_WIN32_NT      EQUATE(2)

VER_PLATFORM_WIN32_WINDOWS EQUATE(1)

VER_PLATFORM_WIN32S        EQUATE(0)



OVI                    GROUP,PRE(OVI)

OVI:dwOSVersionInfoSize  DWORD

OVI:dwMajorVersion       DWORD

OVI:dwMinorVersion       DWORD

OVI:dwBuildNumber        DWORD

OVI:dwPlatformId         DWORD

OVI:szCSDVersion         CHAR,DIM(128)

                       END



! Code Section

! Define version of Windows

OVI:dwOSVersionInfoSize = SIZE(OVI)

IF GetVersionEx( ADDRESS(OVI) ) = 0

  MESSAGE('Unable to determine Windows version','Error')

ELSE

  CASE OVI:dwPlatformId

  OF VER_PLATFORM_WIN32S

    g:OSType = 0

    MESSAGE('Unable to run under Win32s - get a real OS','Error')

  OF VER_PLATFORM_WIN32_WINDOWS

    g:OSType = 1

    g:WindowsPath = LOWER(GetRegistry('SoftwareMicrosoftWindowsCurrentVersion',|

                                      'SystemRoot','',HKEY_LOCAL_MACHINE))

  OF VER_PLATFORM_WIN32_NT

    IF OVI:dwMajorVersion = 5

      g:OSType = 1 ! Windows 2000

    ELSE

      g:OSType = 2 ! Windows NT

    END

    g:WindowsPath = LOWER(GetRegistry('SoftwareMicrosoftWindows NTCurrentVersion',|

                                      'SystemRoot','',HKEY_LOCAL_MACHINE))

  ELSE

    MESSAGE('Unable to determine which Windows you have','Error')

  END

END



! Register as service only under Windows 9x

IF g:OSType = 1 ! Win9x

  loc:CurrentProcessId = GetCurrentProcessId()

  r# = RegisterServiceProcess( loc:CurrentProcessId, 1)

END

How to define IP address of computer?

Tue, 17 Jul 2007 08:11:00 GMT

  PROGRAM
  MAP
    MODULE('wsock32.dll')
WSAStartup(SIGNED, *lpWSAData),SIGNED,RAW,PASCAL,NAME('WSAStartup')
Inet_NToA(ULONG),ULONG,RAW,PASCAL,NAME('Inet_NToA')
WSACleanup(),SIGNED,RAW,PASCAL,NAME('WSACleanUP')
GetHostByName(*CSTRING),LONG,RAW,PASCAL,NAME('GetHostByName')
GetHostName(*CSTRING,LONG),LONG,RAW,PASCAL,NAME('GetHostName')
    END
  END

lpWSAData         GROUP,TYPE
wVersion            SIGNED
wHighVersion        SIGNED
szDescription       CSTRING(257)
szSystemStatus      CSTRING(129)
iMaxSockets         USHORT
iMaxUpdDg           USHORT
lpVendorInfo        LONG
END
InetAddr          ULONG
WSAData1          GROUP(lpWSAData)
END
LocalHost         CSTRING(100)
LocalIP           CSTRING(15)

  CODE
  err# = WSACleanUP()
  CLEAR(WSAData1)
  IF WSAStartup(2,WSAData1) < 0
    RETURN
  END
  err# = GetHostName(LocalHost,100)
  InetAddr = GetHostByName(LocalHost)
  IF InetAddr
    PEEK(InetAddr + 12,InetAddr)
    PEEK(InetAddr,InetAddr)
    PEEK(InetAddr,InetAddr)
    PEEK(Inet_NToA(InetAddr),LocalIP)
  END
  err# = WSACleanup()
  MESSAGE(LocalIP)

How to call WinAPI functions from Clarion applications?

Tue, 17 Jul 2007 08:03:00 GMT

For the first time it is necessary to declare in MAP-section the prototype of WinAPI-function in terms of Clarion, i.e. to replace C-data types with corresponding data types of Clarion. You may use service program winapi.exe which is delivered with Clarion. Its database content great variety already adapted prototypes for Clarion. As soon as procedure will be prototyped correctly, it may be used as usual Clarion-function.

Example:

! WinAPI prototype
LRESULT SendMessage(HWND hWnd,
UINT Msg,
WPARAM wParam,
LPARAM lParam
);

! Clarion prototype
SendMessage(UNSIGNED hWnd,UNSIGNED Msg,UNSIGNED wParam,LONG lParam), |
UNSIGNED,PASCAL,RAW,NAME('SendMessageA'),PROC

It should to pay special attention to attribute of procedure NAME. The matter is that functions WinAPI can be used both for usual null-terminated strings and for Unicode-string. Therefore Windows libraries export at least two names for the same function. Depending on types of string function will work, its name can be terminated by letter A (null-terminated strings) or W (wide strings). One more attribute demanding attention - RAW. It is necessary to specify it in the prototype of function if among its parameters there is a CSTRING-parameter. This attribute defines, that string parameter will be passed to procedure by its address. For detail information read the help.

How to get unique identifier GUID?

Tue, 17 Jul 2007 07:59:00 GMT

  PROGRAM
  MAP
    MODULE('winapi')
CoCreateGuid(*?),UNSIGNED,PASCAL,RAW,DLL(1),NAME('CoCreateGuid')
StringFromGUID2(*?,*?,LONG cchMax),UNSIGNED,PASCAL,RAW,NAME('StringFromGUID2')
WideCharToMultiByte(UNSIGNED CodePage=0,USHORT dwFlags=0,|
*? lpWideCharStr,LONG cchWideChar,*? lpMultiByteStr,|
LONG cbMultiByte,? lpDefaultChar,|
BYTE lpUsedDefaultChar), |
UNSIGNED,PASCAL,RAW,NAME('WideCharToMultiByte')
    END
  END

pGuid  STRING(16)
buf    STRING(128)
buf2   STRING(64)
cbSize LONG

  CODE
  IF CoCreateGuid(pGUID)
    MESSAGE('','GUID is not received.')
  ELSE
    IF StringFromGuid2(pGuid,buf,SIZE(buf)/2)
      cbSize = WideCharToMultiByte(, , buf, -1, buf2, SIZE(buf2), 0,0)
      IF cbSize > 0
        buf2 = buf2[1 : cbSize]
        SETCLIPBOARD(CLIP(buf2))
        MESSAGE(buf2,'GUID is received and placed into clipboard.')
      END
    ELSE
      MESSAGE('Buffer is too small for accepted value.')
    END
  END